Sorting lists

[Kilinich]

I don't know yet where to use it , but it's pretty cool.
Now you can sort huge lists with no lags.

Code: Select all

Scene.my.QSort := (array, size)=>{
    size > 2 ? {
        b := math.toint(size / 2);
        low := []; lowCount := 0;
        high := []; highCount := 0;
        for(b, (i)=>{
            array(i) > array(b) ? {
                highCount = highCount + 1; high = high ++ [array(i)]
            } : {
                lowCount = lowCount + 1; low = low ++ [array(i)]
            }
        });
        for(size - b - 1, (i)=>{
            array(i + b + 1) > array(b) ? {
                highCount = highCount + 1; high = high ++ [array(i + b + 1)]
            } : {
                lowCount = lowCount + 1; low = low ++ [array(i + b + 1)]
            }
        });
        (lowCount > 0 ? Scene.my.QSort(low, lowCount) : []) ++ [array(b)] ++ (highcount > 0 ? Scene.my.QSort(high, highCount) : [])
    } : {size == 2 ? {array(0) < array(1) ? array : [array(1), array(0)]} : array}
};


Scene.my.qSort([10,23,3,1,2,55],6) produce [1,2,3,10,23,55]

[Kilinich]

And little more complex version for sorting 2-dimensional tables:
key is index of key element 0= first

Code: Select all

Scene.my.QSortTable := (array, size, key)=>{
    size > 2 ? {
        b := math.toint(size / 2);
        low := [];
        lowCount := 0;
        high := [];
        highCount := 0;
        for(b, (i)=>{
            array(i)(key) > array(b)(key) ? {
                highCount = highCount + 1;
                high = high ++ [array(i)]
            } : {
                lowCount = lowCount + 1;
                low = low ++ [array(i)]
            }
        });
        for(size - b - 1, (i)=>{
            array(i + b + 1)(key) > array(b)(key) ? {
                highCount = highCount + 1;
                high = high ++ [array(i + b + 1)]
            } : {
                lowCount = lowCount + 1;
                low = low ++ [array(i + b + 1)]
            }
        });
        (lowCount > 0 ? Scene.my.QSortTable(low, lowCount, key) : []) ++ [array(b)] ++ (highcount > 0 ? Scene.my.QSortTable(high, highCount, key) : [])
    } : {size == 2 ? {array(0)(key) < array(1)(key) ? array : [array(1), array(0)]} : array}
};

Scene.my.QSortTable([[10,"Ten"],[1,"One"],[2,"Two"],[5,"Five"],[-1,"Minus one"]], 5, 0)
result is:
[[-1,"Minus one"],[1,"One"],[2,"Two"],[5,"Five"],[10,"Ten"]]

[Matten]

It looks good, but is somebody ever going to use this?

[Mystery]

Yep, I'll be looking into this, looks promising could save me a lot of time.

[Kilinich]

It looks good, but is somebody ever going to use this?

I am